Language server formatter

[BlindingDark]

Hello there.
I'm trying to combine lsp and apheleia and here is the result.

You must be in a buffer with lsp-mode enabled to format it, so here we format in the original buffer, but apply the result to scratch.

(defun apheleia-lsp-formatter-buffer (buffer scratch)
  (with-current-buffer buffer
    (if (lsp-feature? "textDocument/formatting")
        (let ((edits (lsp-request
                      "textDocument/formatting"
                      (lsp--make-document-formatting-params))))
          (unless (seq-empty-p edits)
            (with-current-buffer scratch
              (lsp--apply-text-edits edits 'format)))))))

(cl-defun apheleia-lsp-formatter
    (&key buffer scratch formatter callback &allow-other-keys)
  (apheleia-lsp-formatter-buffer buffer scratch)
  (funcall callback))

And then use it in any mode you want

(add-to-list 'apheleia-formatters '(apheleia-lsp . apheleia-lsp-formatter))
(setf (alist-get 'elixir-mode apheleia-mode-alist)
      '(apheleia-lsp))
(setf (alist-get 'python-mode apheleia-mode-alist)
      '(apheleia-lsp))

Hope it can help you.