Test Patient Compartment - Compare search forms (TestID13)

[nir-r]

Test13
If a patient compartment is declared (CapabilityStatement.rest.compartment) - check the equivalence of the 2 search forms below (for existing and non existing patients)

GET [base]/Patient/333/Condition
GET [base]/Condition?patient=333

[nir-r]

/*Test Patient Compartment - Compare search forms (TestID13)*/
/*General notes 1 - search equivalence => test searching by resourceType AND patient & in-patient compartment are equivalent*/
/*General notes 2 - test inclusion based on secondary/less common inclusion elements such as Condition.asserter (vs the obvious Condition.subject)*/ 
/*General notes 3 - 0 results in both searches isn't enough as it doesn't test inclusion by secondary elements*/
/*General notes 4 - it's ok to test primary and secondary inclusion element for different patients*/

(  

  /*List resourceTypes and Paths within them that point to Compartment Patient*/
  $resourceTypesPathsToPatientCompartment := 
  (
    /*List all paths relevant for Compartment Patient https://hl7.org/fhir/R4/compartmentdefinition-patient.json*/
      $PatientCompartmentResourcesParams := $readFile('compartmentdefinition-patient.json').resource[$exists(param)].param.{'resourceType':%.code, 'SPname':$}
  
    /*SearchParams reousrceTypes and paths ONLY for SPs refering Patient*/
      ;$SPreousrceTypesPaths := (
            $stpA := $readFile('search-parameters.json').entry.resource[
            type='reference' 
            and 'Patient' in target 
            and $not('Patient' in base)].{'SPname':name, 'expressionSplit':$split(expression,"|")}
          
          /*trim and remove where condition*/
          ;$stpB := $stpA.expressionSplit.{'expressionSplit':$substringBefore($trim($),'.where('), 'SPname':%.SPname}

          /*Extract resourceType*/
          ;$stpC := $stpB.{'SPpath':$substringAfter(expressionSplit,'.'),'fullSPpath':expressionSplit,'SPname':SPname,'resourceType':$substringBefore(expressionSplit,'.')}
        )
  
    /*Inner join defentions from compartmentdefinition-patient.json and search-parameters.json => list resourceTypes and paths to search*/
      ;$PatientCompartmentResourcesParams@$PCRP.($SPreousrceTypesPaths[$PCRP.resourceType=$.resourceType and $PCRP.SPname = $.SPname].{'resourceType':$.resourceType, 'SPpath':$.SPpath})
    )

  /*Check in CapStat if server declares support for patient compartment if not => warning and continue (may support w/o declaring)*/
    ;'http://hl7.org/fhir/CompartmentDefinition/patient' in $capabilities().rest.compartment ? '' : $info('Warning - No support for Patient resource type on server capability statment while trying to check patient compartment. Test continued')

  /*Extract 1 instance per resourceType&inclusion path which is part of the Compartment Patient*/
    ;$SampledResources := $readFile('SampledResources.json')

    ;$x := $resourceTypesPathsToPatientCompartment@$RTPTPC.($SampledResources[$RTPTPC.resourceType=$.resourceType and $exists($RTPTPC.SPpath)][0].{
      'id':id
      ,'resourceType':resourceType
      ,'SPpath':$RTPTPC.SPpath
      ,'SPpathValue':$eval($RTPTPC.SPpath).reference
      ,'PatiendID':$substringAfter($eval($RTPTPC.SPpath).reference,'/Patient/')
      })

  /*Test search equivalence for each sampled resource type and path*/
    ;$x.(
      /*Search instance in patient compartment*/
        $searchByCompartment := $.$search('Patient/' & $.PatiendID & '/' &$.resourceType, {'_id':$.id})

      /*Search instance in resourceType endpoint*/
        ;$searchByResourceType := $.$search($.resourceType,{'patient':$.PatiendID,'_id':$.id})

      /*Compare search resoults*/
        ;$merge([$,{'searchEquivalence':($searchByCompartment.entry = $searchByResourceType.entry),'$searchByCompartment':$searchByCompartment,'$searchByResourceType':$searchByResourceType}])
    )
)